Отправлено A_S_N 16 февраля 2005 г. 22:47 В ответ на: А кто знает, как в ASM51 перевести HEX число в DEC, по наикратчайшему алгоритму. отправлено nikolaus 16 февраля 2005 г. 21:45

B16BCDD:
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;Подпрограмма преобразования целового 16-ти битного двоичного числа без ;знака в двоично-десятичное.
;Вход: R5R4   - 16-ти разрядное двоичное число.
;Вход: R1R2R3 - двоично-десятичные цифры (R1 - десятки тысяч)
;Используемые регистры: R5, R4, B, A
;Требует свободных байт в стеке: 2
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 mov   R1,#0
 mov   R2,#0
 mov   R3,#0      ; обнулить результат
 mov   B, #16
 sjmp  B16BCDD_2 ;
B16BCDD_1:
 mov   A,R3
 add   A,R3
 da    A
 mov   R3,A
 mov   A,R2
 addc  A,R2
 da    A
 mov   R2,A
 mov   A,R1
 addc  A,R1
 mov   R1,A   ; R1R2R3 умножено на 2 по правилам 10-чной системы
B16BCDD_2:
 mov   A,R4
 rlc   A
 mov   R4,A
 mov   A,R5
 rlc   A
 mov   R5,A   ; число сдвинуто влево
 mov   A,R3
 addc  A,#0
 mov   R3,A   ; добавили старший разряд к единицам результата R1R2R3
 djnz  B,B16BCDD_1; зацикливание 
 ret

• Красивый процедур. И мега простой. Надо было в своё время на олимпиады-то ходить... а я их не любил, т.к. не видел прикладного смысла. — 507   (17.02.2005 00:10, пустое)
• ))))))я тоже ее на 5тый год только прочувствовал)))) — колян безпарольный   (16.02.2005 23:00, пустое)
• Уже довольно давно пишу для 51ого, а команду DA A увидел впервые, от_млять :) а с кодом надо будет на свежую голову посидеть. — 507   (16.02.2005 22:57, пустое)