Отправлено PicoDev 28 марта 2004 г. 21:25 В ответ на: Ответ: Отрывок от поэмы "USB everywhere..." здесь:(+), Input, Output, and Mask Bits Output (AND_OR) отправлено PicoDev 28 марта 2004 г. 11:56

$GEN ; Enable Macro Listing
;;--------------------------------------------------------
;; File: FX2IOAsm.a51
;; Contents: This file contains code for access
;; to the internal resources FX2 chip.
;; designed by Serge Sudja
;; Copyright (c) 2003. All rights reserved
;;---------------------------------------------------------
public _hPortIn, _hPortOut, _hPortAndOr

;----------------------------------------------------------
sfr Port = 0xB0;
sbit BitPort = 0xB0;
;**********************************************************
FX2IOAsm SEGMENT CODE PAGE
rseg FX2IOAsm
;**********************************************************
;==========================================================
;byte=R7 hPortIn(port=R7)
;------------------------
_hPortIn:
MOV A, R7
MOV DPTR, #hPortIn1+01H
MOVX @DPTR, A

hPortIn1:
MOV R7, Port
RET
;==========================================================
; void hPortOut(port=R7, data=R5)
;-----------------------------------
_hPortOut:
MOV A, R7
MOV DPTR, #hPortOut1+01H
MOVX @DPTR, A

hPortOut1:
MOV Port, R5
RET
;==========================================================
;hPortAndOr(port=R7, and=R5, or=R3)
;-----------------------------------
_hPortAndOr:
MOV A, R7
MOV DPTR, #hPortAndOr1+01H
MOVX @DPTR, A

MOV DPTR, #hPortAndOr1+05H
MOVX @DPTR, A
hPortAndOr1:
MOV A,Port
ANL A,R5
ORL A,R3
MOV Port,A
RET
;==========================================================
;**********************************************************
end