Отправлено -=Shura=- 23 сентября 2003 г. 16:19 В ответ на: Помогите!! Как симулировать прерывания в C-SPY для MSP430???? отправлено furryoo 23 сентября 2003 г. 14:31

#include  "msp430x11x.h"
;******************************************************************************
;   MSP-FET430x110 Demo - Timer_A Toggle P1.0, CCR0 Contmode ISR, DCO SMCLK 
;
;   Description; Toggle P1.0 using using software and TA_0 ISR. Toggle rate is 
;   set at 50000 DCO/SMCLK cycles. Default DCO frequency used for TACLK. 
;   Durring the TA_0 ISR P0.1 is toggled and 50000 clock cycles are added to 
;   CCR0.  TA_0 ISR is triggered exactly 50000 cycles. CPU is normally off and
;   used only durring TA_ISR.  
;   MCLK = SMCLK = TACLK = DCO ~ 800k 
;
;                MSP430F1121
;             -----------------
;         /|\|              XIN|-  
;          | |                 |
;          --|RST          XOUT|-
;            |                 |
;            |             P1.0|-->LED
;
;   M.Buccini
;   Texas Instruments, Inc
;   January 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     0F000h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #300h,SP                ; Initialize stackpointer
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop WDT
SetupTA     mov.w   #TASSEL1+TACLR,&TACTL   ; SMCLK, clear TAR
SetupC0     mov.w   #CCIE,&CCTL0            ; CCR0 interrupt enabled
            mov.w   #50000,&CCR0            ; 
SetupP1     bis.b   #001h,&P1DIR            ; P1.0 output 
            bis.w   #MC1,&TACTL             ; Start Timer_a in continous mode
            eint                            ; Enable interrupts
                                            ;              
Mainloop    bis.w   #CPUOFF,SR              ; CPU off
            nop                             ; Required for C-spy
                                            ;
;------------------------------------------------------------------------------ 
TA0_ISR;    Toggle P1.0
;------------------------------------------------------------------------------ 
            xor.b   #001h,&P1OUT            ; Toggle P1.0
            add.w   #50000,&CCR0            ; Add Offset to CCR0
            reti                            ;     
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430x11x1          
;------------------------------------------------------------------------------ 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            ORG     0FFF2h                  ; Timer_A0 Vector
            DW      TA0_ISR                 ; 
            END

• бл...... асму то мы не обучены :(. А на Си его ни как нельзя заставить симулить прерываия? — furryoo   (23.09.2003 16:55, пустое)
  • Без понятия. Но думаю, что можно. — -=Shura=-   (23.09.2003 16:59, пустое)