Отправлено Baser 29 мая 2002 г. 14:35 В ответ на: ранее в конфе всплывал такой алгоритм ... отправлено d!ma_bo 29 мая 2002 г. 11:21

Заточен на применение в связке с ИАР-С:

;---------------------------------------------------------------;
;         Binary to BCD convert 1-byte number                   ; 
; Function: int BinBCD1 (char Num);                             ; 
; Input:  r16   -   input binary 1-byte number,                 ;
; Temp:   r18:r17 - output BCD 2-byte number,                   ;
; Output: r17:r16 -     ---"--"---                              ;
;---------------------------------------------------------------;
    PUBLIC  BinBCD1
BinBCD1:
    #define tmp     r19
    #define Step    r20
        clr     r17
        clr     r18
        ldi     Step,8      ;  shift steps
         
bcd10:  lsl     r16
        rol     r17
        rol     r18
        dec     Step
        breq    bcd15
   
bcd11:  mov     tmp,r17
        andi    tmp,b'00001111
        cpi     tmp,5
        brlo    bcd12
        subi    r17,-0x03   ; Out1 low nibble >= 5
   
bcd12:  mov     tmp,r17
        swap    tmp
        andi    tmp,b'00001111
        cpi     tmp,5
        brlo    bcd13
        subi    r17,-0x30   ; Out1 high nibble >= 5
   
bcd13:  mov     tmp,r18
        andi    tmp,b'00001111
        cpi     tmp,5
        brlo    bcd14
        subi    r18,-0x03   ; Out2 low nibble >= 5 
bcd14:  rjmp    bcd10 
         
    #undef  tmp
    #undef  Step
bcd15:  mov     r16,r17
        mov     r17,r18 
        ret
;---------------------------------------------------------------;