|
|
;Программа мигает лампочкой и параллельно обслуживает прерывания от
;последовательного порта - возвращает все пришедшие с машины символы обратно.
.include "2313def.inc"
rjmp main_program ;Переход к основной части программы
nop ;
nop ;
nop ;
nop ;
nop ;
nop ;
;Обработчик по приему символа
push r16 ;Сохранить R16
push r0 ;Сохранить
in r0,sreg ;SREG
in r16,udr ;Прочитаем принятый символ
sbic usr,fe ;Была ошибка приема ?
rjmp to_reti ;Да - возврат из подпрограммы
rcall transmitter ;Передать символ
to_reti: out sreg,r0 ;Восстановить
pop r0 ;SREG
pop r16 ;Восстановить R16
reti ;Возврат из обработчика
main_program:
sei ;Разрешить прерывания
ldi r16,$df ;Настроить начало стека
out spl,r16 ;на конец SRAM
rcall set_serial_mode ;Настроить последовательный порт
sbi ddrb,7 ;Настроить порт PB.7 на вывод данных
next: sbi portb,7 ;Мигаем
rcall long_delay ;...
cbi portb,7 ;лампочкой
rcall long_delay ;...
rjmp next ;Имитация полезной работы программы -
;мигание лампочки
;Процедура настраивает последовательный интерфейс. Процедура не изменяет
;флагов в регистре SREG
set_serial_mode:
push r16 ;Сохранить R16
sbi ucr,rxcie ;Разрешить прерывания по приему символа
sbi ucr,rxen ;Разрешить работу приемника
sbi ucr,txen ;Разрешить работу передатчика
cbi portd,0 ;Не использовать внутренний PULLUP
;для входа приемника
ldi r16,32 ;Скорость ~9469,6 бит/с. для кварца 5 МГц
out ubrr,r16 ;Загрузить скорость в UBRR
pop r16 ;Восстановить R16
ret ;Возврат из подпрограммы
;Процедура передает байт в регистре R16 через UART. Процедура не изменяет
;флагов в регистре SREG
transmitter:
sbis usr,5 ;Бит UDRE=1 ?
rjmp transmitter ;Нет - ждем момента: UDRE=1
out udr,r16 ;Да - передать байт
wait_end: sbis usr,6 ;Бит TXC=1 (передача окончена?)
rjmp wait_end ;Нет - ждем окончания передачи
cbi usr,6 ;Да - сбросим бит TXC
ret ;Возврат из подпрограммы
;Процедура формирует задержку примерно 52 миллисекунды для кварца на 5 Мгц
delay_52ms:
push r17 ;Сохранить R17
push r0 ;Сохранить
in r0,sreg ;SREG
in r17,timsk ;Запретить прерывания
andi r17,$fd ;по
out timsk,r17 ;переполнению Т/С0
;
ldi r17,$00 ;Считать от нуля
out tcnt0,r17 ;до 255
ldi r17,$05 ;Коэффициент деления
out tccr0,r17 ;равен 1024
wait_end_pause: ;
in r17,tifr ;Проверим, было ли уже
sbrs r17,1 ;преполнение
rjmp wait_end_pause ;таймера / счетчика "0"
ori r17,$02 ;Да, было - очистим
out tifr,r17 ;бит переполнения
out sreg,r0 ;Восстановить
pop r0 ;SREG
pop r17 ;Восстановить R17
ret ;Возврат из подпрограммы
;Процедура формирует задержку примерно 520 миллисекунд для кварца на 5 Мгц
long_delay:
push r16 ;Сохранить R17
push r0 ;Сохранить
in r0,sreg ;SREG
ldi r16,10 ;Цикл 16 раз
long_long: ;
rcall delay_52ms ;Вызов короткой задержки
dec r16 ;Уменьшить R16 на 1
brne long_long ;Пока R16<>0, продолжать задержку
out sreg,r0 ;Восстановить
pop r0 ;SREG
pop r16 ;Восстановить R17
ret ;Возврат из подпрограммы
|
|
E-mail: 
info@telesys.ru
