[an error occurred while processing this directive]
|
Во-первых, вот твой текст без потерь форматирования:
unsigned char brev(unsigned char u) {
#define BR(n) if(u&(1 << n)) b |= (1 << n);
unsigned char b = 0;
BR(0);
BR(1);
BR(2);
BR(3);
BR(4);
BR(5);
BR(6);
BR(7);
return b;
#undef BR
}
А вот мои АСМ-варианты для AVR:
mirror8a:
;Adjacent 1-, 2- and 4-bit field permutation method
;r16 = bit reversed r16
;15 clocks + ret
mov r17,r16 ;Swap odd and even 1-bit fields
andi r16,$55
lsl r16
andi r17,$AA
lsr r17
or r16,r17
mov r17,r16 ;Swap odd and even 2-bit fields
andi r16,$33
lsl r16
lsl r16
andi r17,$CC
lsr r17
lsr r17
or r16,r17
swap r16 ;Swap odd and even 4-bit fields
ret
mirror8b:
;ROL-ROR-SWAP method
;r16 = bit reversed r16
;14 clocks + ret
mov r17,r16 ;76543210 c
rol r16 ;6543210c 7
ror r17 ;77654321 0
rol r16 ;543210c0 6
ror r17 ;67765432 1
rol r16 ;43210c01 5
ror r17 ;56776543 2
rol r16 ;3210c012 4
ror r17 ;45677654 3
rol r16 ;210c0123 3
andi r16,$0F ;oooo0123
andi r17,$F0 ;4567oooo
or r16,r17 ;45670123
swap r16 ;01234567
ret
mirror16:
;ROL-ROL method for mirroring 2 bytes simultaneously
;r6 = bit reversed r7, r7 = bit reversed r6
;17 clocks + ret
;Initial state: r6 = hgfedcba
; r7 = HGFEDCBA
; CY = y
rol r6 ;gfedcbay h
ror r7 ;hHGFEDCB A
rol r6 ;fedcbayA g
ror r7 ;ghHGFEDC B
rol r6 ;edcbayAB f
ror r7 ;fghHGFED C
rol r6 ;dcbayABC e
ror r7 ;efghHGFE D
rol r6 ;cbayABCD d
ror r7 ;defghHGF E
rol r6 ;bayABCDE c
ror r7 ;cdefghHG F
rol r6 ;ayABCDEF b
ror r7 ;bcdefghH G
rol r6 ;yABCDEFG a
ror r7 ;abcdefgh H
rol r6 ;ABCDEFGH y
ret
Где-то еще лежат варианты на полубайтную и байтную таблицу - полубайтная всего на пару тактов быстрее вышеприведенных и жрет регистры, так что неинтересно. Байтовая всех быстрее, но 256 байт таблица. А твой вариант даже на АСМ будет медленнее моих нетабличных раза в 1.5-2
E-mail: info@telesys.ru