Отправлено AntZ 14 октября 2003 г. 12:10 В ответ на: Погодите а с каким процессаром вы работаете? Странный CMD. отправлено Paren 14 октября 2003 г. 12:01

/******************************************************************************/
/* LNK.CMD - COMMAND FILE FOR LINKING C PROGRAMS                              */
/*                                                                            */
/* 5510 DSK                                                                   */
/*                                                                            */
/******************************************************************************/
-stack    0x2000		/* Primary stack size   */
-sysstack 0x1000		/* Secondary stack size */
-heap     0x1000		/* Heap area size       */

-c                    		/* Use C linking conventions: auto-init vars at runtime */
-u _Reset             		/* Force load of reset interrupt handler                 */
-iC:/TIeval22/c5500/cgtools/lib	/* rts55 directory path */
-lrts55x.lib           		/* C and C++ run-time library support */
/* MEMORY MAP IS IN *BYTES*! */
MEMORY
{
 
 PAGE 0:  /* ---- Unified Program/Data Address Space ---- */
 	/* OnChip memory */
 	DARAM00_07 (RWIX): origin = 0x000100 length = 0x00FF00	/* 64K BYTES DARAM */
 	SARAM00_07 (RWIX): origin = 0x010000 length = 0x010000	/* 64K BYTES SARAM */
 	SARAM08_15 (RWIX): origin = 0x020000 length = 0x010000	/* 64K BYTES SARAM */
 	SARAM16_23 (RWIX): origin = 0x030000 length = 0x010000	/* 64K BYTES SARAM */
 	SARAM24_31 (RWIX): origin = 0x040000 length = 0x00FF00	/* 64K-256B BYTES SARAM */
 	VECS (RIX):        origin = 0x04ff00 length = 0x000100  /* 256-byte interrupts vectors */
 	ROM (RIX):         origin = 0xFF8000 length = 0x008000	/* 32K BYTES ROM */
 
 PAGE 2:  /* -------- 64K-word I/O Address Space -------- */
	IOPORT (RWI) : origin = 0x000000, length = 0x01FFFF
}
 
/* SPECIFY THE SECTIONS ALLOCATION INTO MEMORY */
SECTIONS
{
   .text     > SARAM00_07    PAGE 0  /* Code                       */
   /* These sections must be on same physical memory page   */
   /* when small memory model is used                       */
   .data     > SARAM08_15    PAGE 0  /* Initialized vars           */
   
   .bss      > DARAM00_07    PAGE 0  /* Global & static vars       */
   .const    > DARAM00_07    PAGE 0  /* Constant data              */
   .sysmem	 > DARAM00_07    PAGE 0  /* Dynamic memory (malloc)    */
   .stack    > DARAM00_07    PAGE 0  /* Primary system stack       */
   .sysstack > DARAM00_07    PAGE 0  /* Secondary system stack     */
   
   .cio      > SARAM00_07    PAGE 0  /* C I/O buffers              */
   /* These sections may be on any physical memory page     */
   /* when small memory model is used                       */
   .switch   > SARAM00_07    PAGE 0  /* Switch statement tables    */
   .cinit    > SARAM00_07    PAGE 0  /* Auto-initialization tables */
   .pinit    > SARAM00_07    PAGE 0  /* Initialization fn tables   */
   .vectors  > VECS          PAGE 0  /* Interrupt vectors          */
   
   .ioport   > IOPORT        PAGE 2  /* Global & static IO vars    */
}